在 Emacs 里面使用 Stardict

Contents

使用 tooltip 显示结果
打开一个 buffer 来显示结果

Stardict 是 Linux 下面很好用的一个辞典，不过如果在 Emacs 里面偶尔要查 一个词还要切换到 Stardict 那里去就太麻烦了，正好 Stardict 提供了一个命 令行的接口可以用，于是我写了一个调用 sdcv (即 Stardict 的命令行接口) 来查单词的小扩展。

使用 tooltip 显示结果

这个函数的功能相当有限，就是直接把参数传给 sdcv ，然后把结果显示出来， 但是对于我来说基本上已经够用而且很好用了：

;; author: pluskid
;; 调用 stardict 的命令行接口来查辞典
;; 如果选中了 region 就查询 region 的内容，
;; 否则就查询当前光标所在的词
(global-set-key (kbd "C-c d") 'kid-star-dict)
(defun kid-star-dict ()
  (interactive)
  (let ((begin (point-min))
        (end (point-max)))
    (if mark-active
        (setq begin (region-beginning)
              end (region-end))
      (save-excursion
        (backward-word)
        (mark-word)
        (setq begin (region-beginning)
              end (region-end))))
    ;; 有时候 stardict 会很慢，所以在回显区显示一点东西
    ;; 以免觉得 Emacs 在干什么其他奇怪的事情。
    (message "searching for %s ..." (buffer-substring begin end))
    (tooltip-show
     (shell-command-to-string
      (concat "sdcv -n "
              (buffer-substring begin end))))))

我把它绑定到了 C-c d 上面，这样就可以很方便地查单词了。呵呵！效果如下， 还不错哟！

不过有时候有些音标显示不出来，这个是比较头痛的，我现在用的是 Emacs 22 ，我发现可以通过 ~/.Xresources 来配置它的字符集，记得 Stardict 在安装的 时候建议安装 ttf-freefont ，那个就是用来显示音标的啦！为了让 Emacs 能够 使用这个字体，必须把他加入 X 核心字体的路径里面，具体请参见这里。

打开一个 buffer 来显示结果

Tooltip 的方式有时候工作不是那么理想，而且在终端下不可能显示 tooltip ，所以我又做了一个打开一个 buffer 来显示查询结果的函数。

;; author: pluskid
;; 调用 stardict 的命令行程序 sdcv 来查辞典
;; 如果选中了 region 就查询 region 的内容，否则查询当前光标所在的单词
;; 查询结果在一个叫做 *sdcv* 的 buffer 里面显示出来，在这个 buffer 里面
;; 按 q 可以把这个 buffer 放到 buffer 列表末尾，按 d 可以查询单词
(global-set-key (kbd "C-c d") 'kid-sdcv-to-buffer)
(defun kid-sdcv-to-buffer ()
  (interactive)
  (let ((word (if mark-active
                  (buffer-substring-no-properties (region-beginning) (region-end))
                  (current-word nil t))))
    (setq word (read-string (format "Search the dictionary for (default %s): " word)
                            nil nil word))
    (set-buffer (get-buffer-create "*sdcv*"))
    (buffer-disable-undo)
    (erase-buffer)
    (let ((process (start-process-shell-command "sdcv" "*sdcv*" "sdcv" "-n" word)))
      (set-process-sentinel
       process
       (lambda (process signal)
         (when (memq (process-status process) '(exit signal))
           (unless (string= (buffer-name) "*sdcv*")
             (setq kid-sdcv-window-configuration (current-window-configuration))
             (switch-to-buffer-other-window "*sdcv*")
             (local-set-key (kbd "d") 'kid-sdcv-to-buffer)
             (local-set-key (kbd "q") (lambda ()
                                        (interactive)
                                        (bury-buffer)
                                        (unless (null (cdr (window-list))) ; only one window
                                          (delete-window)))))
           (goto-char (point-min))))))))